Escapers Zone

Code: Select all

   #include <zombie_escape>

// Variables
new bool:g_bGiveParachute[33];

// Cvars
new cvar_fall_speed, cvar_give_all;

public plugin_init()
{
	register_plugin("[ReAPI/ZE] Parachute", "1.1", "ReHLDS Team/Raheem");
	RegisterHookChain(RG_PM_AirMove, "PM_AirMove", false);
	
	// Cvars
	cvar_fall_speed = register_cvar("ze_fall_speed", "90");
	cvar_give_all = register_cvar("ze_give_all_parachute", "1");
}

public plugin_natives()
{
	register_native("ze_give_user_parachute", "native_ze_give_user_parachute", 1)
	register_native("ze_remove_user_parachute", "native_ze_remove_user_parachute", 1)
}

public PM_AirMove(const playerIndex)
{
	if (get_pcvar_num(cvar_give_all) == 1 || g_bGiveParachute[playerIndex] && get_member(playerIndex, m_iTeam) == TEAM_CT)
	{
		if (!(get_entvar(playerIndex, var_button) & IN_USE)
		|| get_entvar(playerIndex, var_waterlevel) > 0) {
			return;
		}
		new Float:flVelocity[3];
		get_entvar(playerIndex, var_velocity, flVelocity);
		if (flVelocity[2] < 0.0)
		{
			flVelocity[2] = (flVelocity[2] + 40.0 < -100.0) ? flVelocity[2] + 40.0 : -get_pcvar_float(cvar_fall_speed);
			set_entvar(playerIndex, var_sequence, ACT_WALK);
			set_entvar(playerIndex, var_gaitsequence, ACT_IDLE);
			set_pmove(pm_velocity, flVelocity);
			set_movevar(mv_gravity, 80.0);
		}
	}
}

public native_ze_give_user_parachute(id)
{
	g_bGiveParachute[id] = true
}

public native_ze_remove_user_parachute(id)
{
	g_bGiveParachute[id] = false
}