Code: Select all
/* Plugin generated by AMXX-Studio */
#pragma compress 1
#include <amxmodx>
#include <fakemeta>
#include <fakemeta_util>
#include <engine>
#include <hamsandwich>
#include <xs>
#include <dhudmessage>
#define PLUGIN "Hunter Killer X-15"
#define VERSION "1.0"
#define AUTHOR "Bim Bim Cay"
// Models
#define v_model "models/v_kronos5.mdl"
#define p_model "models/p_kronos5.mdl"
#define w_model "models/w_kronos5.mdl"
#define ef_model "models/ef_kronos5.mdl"
// Sounds
new const Kronos5_Sounds[2][] =
{
"weapons/kronos5-1.wav",
"weapons/kronos5_takeaim.wav"
}
// Sprites
#define ef_esp "sprites/laserbeam.spr"
#define ef_laser "sprites/lgtning.spr"
// Animations
#define ANIM_IDLE 0
#define ANIM_IDLE2 1
#define ANIM_IDLE3 2
#define ANIM_SHOOT1 3
#define ANIM_SHOOT2 4
#define ANIM_SHOOT3 5
#define ANIM_RELOAD1 6
#define ANIM_RELOAD2 7
#define ANIM_DRAW1 8
#define ANIM_DRAW2 9
#define ANIM_SCANACTIVATE 10
#define ANIM_ZOOM 11
#define ANIM_SCANDEACTIVATE 12
#define ANIM_EXTENSION "carbine"
// Entity Classname
#define ZOOM_CLASSNAME "Kronos5_Zoom"
// Configs
#define WEAPON_NAME "weapon_kronos5"
#define WEAPON_BASE "weapon_famas"
#define WEAPON_MAX_CLIP 30
#define WEAPON_DEFAULT_AMMO 90
#define WEAPON_SHOOT_DAMAGE 113.0
#define WEAPON_SHOOT_DAMAGEZ 726.0
#define WEAPON_TIME_NEXT_ATTACK 0.09
#define WEAPON_TIME_NEXT_ATTACKZ 0.75
#define ACTIVATE_AMMO 30
#define SCANMODE_DURATION 5
#define WALLHACK_DISTACE 2000.0
new const TargetColor[3] = {255, 0, 0}
// MACROS
#define Get_BitVar(%1,%2) (%1 & (1 << (%2 & 31)))
#define Set_BitVar(%1,%2) %1 |= (1 << (%2 & 31))
#define UnSet_BitVar(%1,%2) %1 &= ~(1 << (%2 & 31))
#define INSTANCE(%0) ((%0 == -1) ? 0 : %0)
#define IsValidPev(%0) (pev_valid(%0) == 2)
#define IsObserver(%0) pev(%0,pev_iuser1)
#define MUZZLE_INTOLERANCE 100
#define OBS_IN_EYE 4
new g_iszWeaponKey
new g_iForwardDecalIndex
new g_SprLaser, g_SprESP
new g_MaxPlayers
new g_MsgBarTime
// Safety
new g_HamBot
new g_IsConnected, g_IsAlive
public plugin_init()
{
register_plugin(PLUGIN, VERSION, AUTHOR)
// Safety
Register_SafetyFunc()
// Forward
register_forward(FM_UpdateClientData, "fw_UpdateClientData_Post", 1)
register_forward(FM_AddToFullPack, "fw_AddToFullPack_Post", 1)
register_forward(FM_TraceLine, "fw_TraceLine_Post", 1)
register_forward(FM_PlaybackEvent, "fw_PlaybackEvent")
register_forward(FM_SetModel, "fw_SetModel")
unregister_forward(FM_DecalIndex, g_iForwardDecalIndex, 1)
// Think
register_think(ZOOM_CLASSNAME, "fw_Zoom_Think")
// Ham
RegisterHam(Ham_Spawn, "weaponbox", "fw_Weaponbox_Spawn_Post", 1)
RegisterHam(Ham_Think, WEAPON_BASE, "fw_Item_Think")
RegisterHam(Ham_Item_Deploy, WEAPON_BASE, "fw_Item_Deploy_Post", 1)
RegisterHam(Ham_Item_Holster, WEAPON_BASE, "fw_Item_Holster_Post", 1)
RegisterHam(Ham_Item_PostFrame, WEAPON_BASE, "fw_Item_PostFrame")
RegisterHam(Ham_Weapon_Reload, WEAPON_BASE, "fw_Weapon_Reload")
RegisterHam(Ham_Weapon_WeaponIdle, WEAPON_BASE, "fw_Weapon_WeaponIdle")
RegisterHam(Ham_Weapon_PrimaryAttack, WEAPON_BASE, "fw_Weapon_PrimaryAttack")
RegisterHam(Ham_Weapon_SecondaryAttack, WEAPON_BASE, "fw_Weapon_SecondaryAttack")
RegisterHam(Ham_TraceAttack, "func_breakable", "fw_TraceAttack_Entity")
RegisterHam(Ham_TraceAttack, "info_target", "fw_TraceAttack_Entity")
RegisterHam(Ham_TraceAttack, "player", "fw_TraceAttack_Entity")
// Get Maxplayers
g_MaxPlayers = get_maxplayers()
// Get Message ID
g_MsgBarTime = get_user_msgid("BarTime")
// Get the weapon now
register_clcmd("say /get", "Get_MyWeapon")
}
public plugin_precache()
{
precache_model(v_model)
precache_model(p_model)
precache_model(w_model)
precache_model(ef_model)
for(new i = 0; i < sizeof(Kronos5_Sounds); i++)
precache_sound(Kronos5_Sounds[i])
g_SprESP = precache_model(ef_esp)
g_SprLaser = precache_model(ef_laser)
g_iszWeaponKey = engfunc(EngFunc_AllocString, WEAPON_NAME)
g_iForwardDecalIndex = register_forward(FM_DecalIndex, "fw_DecalIndex_Post", 1)
}
public client_putinserver(iPlayer)
{
Safety_Connected(iPlayer)
if(!g_HamBot && is_user_bot(iPlayer))
{
g_HamBot = 1
set_task(0.1, "Register_HamBot", iPlayer)
}
}
public Register_HamBot(iPlayer)
{
Register_SafetyFuncBot(iPlayer)
RegisterHamFromEntity(Ham_TraceAttack, iPlayer, "fw_TraceAttack_Entity")
}
public client_disconnect(iPlayer)
{
Safety_Disconnected(iPlayer)
}
public Get_MyWeapon(iPlayer)
{
Weapon_Give(iPlayer)
}
//**********************************************
//* Forward Hooking *
//**********************************************
public fw_UpdateClientData_Post(iPlayer, sendweapons, CD_Handle)
{
enum
{
SPEC_MODE,
SPEC_TARGET,
SPEC_END
}
static aSpecInfo[33][SPEC_END]
static iTarget
static iSpecMode
static iActiveItem
iTarget = (iSpecMode = IsObserver(iPlayer)) ? pev(iPlayer, pev_iuser2) : iPlayer
if(!is_alive(iTarget))
return FMRES_IGNORED
iActiveItem = get_pdata_cbase(iTarget, 373, 5)
if(!IsValidPev(iActiveItem) || !IsCustomItem(iActiveItem))
return FMRES_IGNORED
if(iSpecMode)
{
if(aSpecInfo[iPlayer][SPEC_MODE] != iSpecMode)
{
aSpecInfo[iPlayer][SPEC_MODE] = iSpecMode
aSpecInfo[iPlayer][SPEC_TARGET] = 0
}
if(iSpecMode == OBS_IN_EYE && aSpecInfo[iPlayer][SPEC_TARGET] != iTarget)
{
aSpecInfo[iPlayer][SPEC_TARGET] = iTarget
static Mode; Mode = get_pdata_int(iActiveItem, 30, 4)
switch(Mode)
{
case 0: Weapon_SendAnim(iPlayer, iActiveItem, ANIM_IDLE)
case 1: Weapon_SendAnim(iPlayer, iActiveItem, ANIM_IDLE2)
case 2: Weapon_SendAnim(iPlayer, iActiveItem, ANIM_IDLE3)
}
}
}
set_cd(CD_Handle, CD_flNextAttack, get_gametime() + 0.001)
return FMRES_HANDLED
}
public fw_AddToFullPack_Post(esState, iE, iEnt, iHost, iHostFlags, iPlayer, pSet)
{
if(!pev_valid(iEnt))
return
static Classname[24]
pev(iEnt, pev_classname, Classname, charsmax(Classname))
if(equali(Classname, ZOOM_CLASSNAME))
{
if(iHost == pev(iEnt, pev_owner))
{
set_es(esState, ES_Effects, get_es(esState, ES_Effects) | EF_NODRAW)
}
}
if(!is_alive(iEnt) || !is_alive(iHost))
return
static iActiveItem; iActiveItem = get_pdata_cbase(iHost, 373, 5)
if(!IsValidPev(iActiveItem) || !IsCustomItem(iActiveItem))
return
if(get_pdata_int(iActiveItem, 30, 4) >= 2)
{
if(get_pdata_int(iHost, 114, 5) == get_pdata_int(iEnt, 114, 5))
return
set_es(esState, ES_RenderFx, kRenderFxGlowShell)
set_es(esState, ES_RenderMode, kRenderTransAdd)
set_es(esState, ES_RenderColor, TargetColor)
set_es(esState, ES_RenderAmt, 8)
}
}
public fw_TraceLine_Post(Float:TraceStart[3], Float:TraceEnd[3], fNoMonsters, iEntToSkip, iTrace) <FireBullets: Enabled>
{
static Float:vecEndPos[3]
get_tr2(iTrace, TR_vecEndPos, vecEndPos)
engfunc(EngFunc_TraceLine, vecEndPos, TraceStart, fNoMonsters, iEntToSkip, 0)
UTIL_GunshotDecalTrace(0)
UTIL_GunshotDecalTrace(iTrace, true)
}
public fw_TraceLine_Post() </* Empty statement */>
{
/* Fallback */
}
public fw_TraceLine_Post() <FireBullets: Disabled>
{
/* Do notning */
}
public fw_PlaybackEvent() <FireBullets: Enabled>
{
return FMRES_SUPERCEDE
}
public fw_PlaybackEvent() </* Empty statement */>
{
return FMRES_IGNORED
}
public fw_PlaybackEvent() <FireBullets: Disabled>
{
return FMRES_IGNORED
}
//**********************************************
//* Weaponbox world model. *
//**********************************************
public fw_SetModel(iEntity) <WeaponBox: Enabled>
{
state WeaponBox: Disabled
if(!IsValidPev(iEntity))
return FMRES_IGNORED
#define MAX_ITEM_TYPES 6
for(new i, iItem; i < MAX_ITEM_TYPES; i++)
{
iItem = get_pdata_cbase(iEntity, 34 + i, 4)
if(IsValidPev(iItem) && IsCustomItem(iItem))
{
engfunc(EngFunc_SetModel, iEntity, w_model)
return FMRES_SUPERCEDE
}
}
return FMRES_IGNORED
}
public fw_SetModel() </* Empty statement */>
{
/* Fallback */
return FMRES_IGNORED
}
public fw_SetModel() <WeaponBox: Disabled>
{
/* Do nothing */
return FMRES_IGNORED
}
public fw_Weaponbox_Spawn_Post(iWeaponBox)
{
if(IsValidPev(iWeaponBox))
{
state (IsValidPev(pev(iWeaponBox, pev_owner))) WeaponBox: Enabled
}
return HAM_IGNORED
}
//**********************************************
//* Weapon's codes. *
//**********************************************
public fw_Item_Deploy_Post(iItem)
{
if(!IsCustomItem(iItem))
return
static iPlayer; iPlayer = get_pdata_cbase(iItem, 41, 4)
set_pev(iPlayer, pev_viewmodel2, v_model)
set_pev(iPlayer, pev_weaponmodel2, p_model)
if(get_pdata_int(iItem, 30, 4))
{
Weapon_SendAnim(iPlayer, iItem, ANIM_DRAW2)
}
else
{
Weapon_SendAnim(iPlayer, iItem, ANIM_DRAW1)
}
set_pdata_string(iPlayer, (492) * 4, ANIM_EXTENSION, -1 , 20)
}
public fw_Item_Holster_Post(iItem)
{
if(!IsCustomItem(iItem))
return
static iPlayer; iPlayer = get_pdata_cbase(iItem, 41, 4)
set_pdata_int(iItem, 55, 0, 4)
set_pdata_int(iItem, 39, 0, 4)
if(get_pdata_int(iItem, 30, 4) >= 2)
{
set_pdata_int(iItem, 30, 0, 4)
Set_ProgessBarTime(iPlayer, 0)
}
}
public fw_Item_PostFrame(iItem)
{
if(!IsCustomItem(iItem))
return HAM_IGNORED
static iPlayer; iPlayer = get_pdata_cbase(iItem, 41, 4)
if(get_pdata_int(iItem, 54, 4))
{
static iClip; iClip = get_pdata_int(iItem, 51, 4)
static iPrimaryAmmoIndex; iPrimaryAmmoIndex = PrimaryAmmoIndex(iItem)
static iAmmoPrimary; iAmmoPrimary = GetAmmoInventory(iPlayer, iPrimaryAmmoIndex)
static iAmount; iAmount = min(WEAPON_MAX_CLIP - iClip, iAmmoPrimary)
set_pdata_int(iItem, 51, iClip + iAmount, 4)
SetAmmoInventory(iPlayer, iPrimaryAmmoIndex, iAmmoPrimary - iAmount)
set_pdata_int(iItem, 54, 0, 4)
}
if(get_pdata_int(iItem, 30, 4) >= 2)
{
static Float:flLastEventCheck; flLastEventCheck = get_pdata_float(iItem, 38, 4)
if(flLastEventCheck < get_gametime())
{
flLastEventCheck = get_gametime() + 0.1
set_pdata_float(iItem, 38, flLastEventCheck, 4)
Scan_Enemies(iPlayer)
Show_FakeCrosshair(iPlayer)
}
}
return HAM_IGNORED
}
public fw_Weapon_Reload(iItem)
{
if(!IsCustomItem(iItem))
return HAM_IGNORED
static iPlayer; iPlayer = get_pdata_cbase(iItem, 41, 4)
static iClip; iClip = get_pdata_int(iItem, 51, 4)
static iPrimaryAmmoIndex; iPrimaryAmmoIndex = PrimaryAmmoIndex(iItem)
static iAmmoPrimary; iAmmoPrimary = GetAmmoInventory(iPlayer, iPrimaryAmmoIndex)
if(min(WEAPON_MAX_CLIP - iClip, iAmmoPrimary) <= 0)
return HAM_SUPERCEDE
static Mode; Mode = get_pdata_int(iItem, 30, 4)
if(Mode >= 2)
return HAM_SUPERCEDE
set_pdata_int(iItem, 51, 0, 4)
ExecuteHam(Ham_Weapon_Reload, iItem)
set_pdata_int(iItem, 51, iClip, 4)
set_pdata_float(iPlayer, 83, 3.0, 5)
set_pdata_float(iItem, 48, 3.0, 4)
if(Mode)
{
Weapon_SendAnim(iPlayer, iItem, ANIM_RELOAD2)
}
else
{
Weapon_SendAnim(iPlayer, iItem, ANIM_RELOAD1)
}
// Cancel ANIM_SCANACTIVATE
set_pdata_int(iItem, 39, 0, 4)
return HAM_SUPERCEDE
}
public fw_Weapon_WeaponIdle(iItem)
{
if(!IsCustomItem(iItem))
return HAM_IGNORED
static iPlayer; iPlayer = get_pdata_cbase(iItem, 41, 4)
ExecuteHamB(Ham_Weapon_ResetEmptySound, iItem)
if(get_pdata_float(iItem, 48, 4) > 0.0)
return HAM_SUPERCEDE
set_pdata_float(iItem, 48, 10.0, 4)
static Mode; Mode = get_pdata_int(iItem, 30, 4)
switch(Mode)
{
case 0: Weapon_SendAnim(iPlayer, iItem, ANIM_IDLE)
case 1: Weapon_SendAnim(iPlayer, iItem, ANIM_IDLE2)
case 2: Weapon_SendAnim(iPlayer, iItem, ANIM_IDLE3)
}
return HAM_SUPERCEDE
}
public fw_Item_Think(iItem)
{
if(!IsValidPev(iItem) || !IsCustomItem(iItem))
return HAM_IGNORED
static iPlayer; iPlayer = get_pdata_cbase(iItem, 41, 4)
if(!is_alive(iPlayer))
return HAM_SUPERCEDE
if(get_pdata_cbase(iPlayer, 373, 5) != iItem)
return HAM_SUPERCEDE
switch(get_pdata_int(iItem, 39, 4))
{
case 1:
{
set_pdata_int(iItem, 39, 0, 4)
Weapon_SendAnim(iPlayer, iItem, ANIM_SCANACTIVATE)
set_pdata_float(iItem, 48, 0.87, 4)
}
case 2:
{
set_pdata_int(iItem, 30, 2, 4)
set_pdata_int(iPlayer, 363, 55, 5)
Set_ProgessBarTime(iPlayer, SCANMODE_DURATION)
set_pdata_int(iItem, 39, 3, 4)
set_pev(iItem, pev_nextthink, get_gametime() + float(SCANMODE_DURATION))
Create_EfZoom(iPlayer)
emit_sound(iPlayer, CHAN_ITEM, Kronos5_Sounds[1], 1.0, 0.4, 0, 94 + random_num(0, 15))
}
case 3:
{
set_pdata_int(iItem, 39, 0, 4)
set_pdata_int(iItem, 30, 0, 4)
set_pdata_int(iPlayer, 363, 90, 5)
set_pdata_float(iPlayer, 83, 0.87, 5)
Weapon_SendAnim(iPlayer, iItem, ANIM_SCANDEACTIVATE)
set_pdata_float(iItem, 48, 0.87, 4)
}
case 4:
{
set_pdata_int(iItem, 39, 0, 4)
set_pdata_int(iItem, 30, 0, 4)
Set_ProgessBarTime(iPlayer, 0)
set_pdata_int(iPlayer, 363, 90, 5)
Weapon_SendAnim(iPlayer, iItem, ANIM_SCANDEACTIVATE)
set_pdata_float(iItem, 48, 0.87, 4)
}
}
return HAM_SUPERCEDE
}
public fw_Weapon_PrimaryAttack(iItem)
{
if(!IsCustomItem(iItem))
return HAM_IGNORED
static iPlayer; iPlayer = get_pdata_cbase(iItem, 41, 4)
static iClip; iClip = get_pdata_int(iItem, 51, 4)
if(iClip <= 0)
{
// No ammo, play empty sound and cancel
if(get_pdata_int(iItem, 45, 4))
{
ExecuteHamB(Ham_Weapon_PlayEmptySound, iItem)
set_pdata_float(iItem, 46, 0.2, 4)
}
return HAM_SUPERCEDE
}
CallOriginalFireBullets(iItem, iPlayer)
static iFlags
static szAnimation[64]
iFlags = pev(iPlayer, pev_flags)
if(iFlags & FL_DUCKING)
{
formatex(szAnimation, charsmax(szAnimation), "crouch_shoot_%s", ANIM_EXTENSION)
}
else
{
formatex(szAnimation, charsmax(szAnimation), "ref_shoot_%s", ANIM_EXTENSION)
}
Player_SetAnimation(iPlayer, szAnimation)
static Mode; Mode = get_pdata_int(iItem, 30, 4)
if(Mode >= 2)
{
Weapon_SendAnim(iPlayer, iItem, ANIM_SHOOT3)
set_pdata_float(iItem, 48, 0.76, 4)
set_pdata_float(iItem, 46, WEAPON_TIME_NEXT_ATTACKZ, 4)
set_pdata_float(iItem, 47, WEAPON_TIME_NEXT_ATTACKZ, 4)
set_pdata_float(iItem, 62, 0.0, 4)
Create_Laser(iPlayer)
if(--iClip <= 0)
{
set_pdata_float(iPlayer, 83, 1.7, 5)
set_pdata_int(iItem, 39, 4, 4)
set_pev(iItem, pev_nextthink, get_gametime() + 0.83)
}
}
else
{
Weapon_SendAnim(iPlayer, iItem, Mode ? ANIM_SHOOT2 : ANIM_SHOOT1)
set_pdata_float(iItem, 48, 0.83, 4)
set_pdata_float(iItem, 46, WEAPON_TIME_NEXT_ATTACK, 4)
set_pdata_float(iItem, 47, WEAPON_TIME_NEXT_ATTACK, 4)
// Cancel ANIM_SCANACTIVATE
set_pdata_int(iItem, 39, 0, 4)
static Float:Velocity[3]
pev(iPlayer, pev_velocity, Velocity)
if(xs_vec_len(Velocity) > 0)
{
Weapon_KickBack(iItem, iPlayer, 0.5, 0.275, 0.2, 0.03, 3.0, 2.0, 10)
}
else if(!(iFlags & FL_ONGROUND))
{
Weapon_KickBack(iItem, iPlayer, 0.9, 0.475, 0.35, 0.0425, 5.0, 3.0, 6)
}
else if(iFlags & FL_DUCKING)
{
Weapon_KickBack(iItem, iPlayer, 0.225, 0.15, 0.1, 0.015, 2.0, 1.0, 10)
}
else
{
Weapon_KickBack(iItem, iPlayer, 0.25, 0.175, 0.125, 0.02, 2.25, 1.25, 10)
}
}
emit_sound(iPlayer, CHAN_WEAPON, Kronos5_Sounds[0], 1.0, 0.4, 0, 94 + random_num(0, 15))
return HAM_SUPERCEDE
}
public fw_Weapon_SecondaryAttack(iItem)
{
if(!IsCustomItem(iItem))
return HAM_IGNORED
static iPlayer; iPlayer = get_pdata_cbase(iItem, 41, 4)
static iClip; iClip = get_pdata_int(iItem, 51, 4)
if(iClip <= 0)
return HAM_SUPERCEDE
static Mode; Mode = get_pdata_int(iItem, 30, 4)
if(Mode >= 2 || Mode <= 0)
return HAM_SUPERCEDE
set_pdata_float(iPlayer, 83, 0.84, 5)
Weapon_SendAnim(iPlayer, iItem, ANIM_ZOOM)
set_pdata_float(iItem, 48, 0.83, 4)
set_pdata_int(iItem, 39, 2, 4)
set_pev(iItem, pev_nextthink, get_gametime() + 0.83)
return HAM_SUPERCEDE
}
public fw_TraceAttack_Entity(iEntity, iAttacker, Float: flDamage) <FireBullets: Enabled>
{
if(!is_connected(iAttacker))
return
static iActiveItem; iActiveItem = get_pdata_cbase(iAttacker, 373, 5)
if(!IsValidPev(iActiveItem))
return
switch(get_pdata_int(iActiveItem, 30, 4))
{
case 2:
{
SetHamParamFloat(3, WEAPON_SHOOT_DAMAGEZ)
return
}
case 1:
{
SetHamParamFloat(3, WEAPON_SHOOT_DAMAGE)
return
}
case 0:
{
SetHamParamFloat(3, WEAPON_SHOOT_DAMAGE)
}
}
if(!is_connected(iEntity))
return
if(get_pdata_int(iEntity, 114, 5) == get_pdata_int(iAttacker, 114, 5))
return
static CheckShoots; CheckShoots = get_pdata_int(iActiveItem, 55, 4)
if(CheckShoots < ACTIVATE_AMMO)
{
CheckShoots++
set_pdata_int(iActiveItem, 55, CheckShoots, 4)
}
else
{
set_pdata_int(iActiveItem, 55, 0, 4)
set_pdata_int(iActiveItem, 30, 1 ,4)
set_pdata_int(iActiveItem, 39, 1, 4)
set_pev(iActiveItem, pev_nextthink, get_gametime() + 0.83)
}
}
public fw_TraceAttack_Entity() </* Empty statement */>
{
/* Fallback */
}
public fw_TraceAttack_Entity() <FireBullets: Disabled>
{
/* Do notning */
}
//**********************************************
//* Effects *
//**********************************************
Scan_Enemies(iPlayer)
{
static Team; Team = get_pdata_int(iPlayer, 114, 5)
static Float:Origin[3]; pev(iPlayer, pev_origin, Origin)
static Float:TargetOrigin[3], Float:TargetDistance
static Float:VecMiddle[3], Float:HitPoint[3], Float:ScaleBoneLen, Float:ScaleBoneWid, Float:DistanceToHitPoint
static Flags, Float:BoneStart[3], Float:BoneEnd[3], Float:OffsetVec[3], Float:EyeLevel[3], Float:TargetHitPointDistance
static Brightness
for(new Target = 1; Target <= g_MaxPlayers; Target++)
{
if(!is_alive(Target))
continue
if(get_pdata_int(Target, 114, 5) == Team)
continue
pev(Target, pev_origin, TargetOrigin)
if(!fm_is_in_viewcone(iPlayer, TargetOrigin))
continue
TargetDistance = get_distance_f(Origin, TargetOrigin)
if(TargetDistance > WALLHACK_DISTACE)
continue
// Trace from me to target, getting hitpoint
engfunc(EngFunc_TraceLine, Origin, TargetOrigin, IGNORE_MONSTERS, 0, 0)
get_tr2(0, TR_vecEndPos, HitPoint)
// I don't want wallhack when I can see the enemy
if(xs_vec_equal(HitPoint, TargetOrigin))
continue
// Get vector from me to target
xs_vec_sub(TargetOrigin, Origin, VecMiddle)
// Get distance from me to hitpoint (nearest wall)
DistanceToHitPoint = vector_distance(Origin, HitPoint)
// Get player flags
Flags = pev(iPlayer, pev_flags)
// Scale
ScaleBoneLen = DistanceToHitPoint / TargetDistance * 50.0
ScaleBoneWid = DistanceToHitPoint / TargetDistance * 150.0
// Get the point 10.0 units away from wall
xs_vec_normalize(VecMiddle, OffsetVec)
xs_vec_mul_scalar(OffsetVec, DistanceToHitPoint - 10.0, OffsetVec)
// Set to eye level
xs_vec_copy(Origin, EyeLevel)
if(Flags & FL_DUCKING)
{
EyeLevel[2] += 12.3
}
else
{
EyeLevel[2] += 17.5
}
xs_vec_add(OffsetVec, EyeLevel, OffsetVec)
// Start and End of a box
xs_vec_copy(OffsetVec, BoneStart)
xs_vec_copy(OffsetVec, BoneEnd)
BoneEnd[2] -= ScaleBoneLen
TargetHitPointDistance = TargetDistance - DistanceToHitPoint
// This is to make the box darker if distance is larger
Brightness = 255
if(TargetHitPointDistance < 2040.0)
{
Brightness = (255 - floatround(TargetHitPointDistance / 12.0))
}
else
{
Brightness = 85
}
Send_BeamPointMessage(iPlayer, BoneStart, BoneEnd, floatround(ScaleBoneWid), Brightness)
}
}
Send_BeamPointMessage(iPlayer, Float:Origin1[3], Float:Origin2[3], Width, Brightness)
{
engfunc(EngFunc_MessageBegin, MSG_ONE_UNRELIABLE, SVC_TEMPENTITY, {0,0,0}, iPlayer) //message begin
write_byte(0)
engfunc(EngFunc_WriteCoord, Origin1[0]) // start position
engfunc(EngFunc_WriteCoord, Origin1[1])
engfunc(EngFunc_WriteCoord, Origin1[2])
engfunc(EngFunc_WriteCoord, Origin2[0]) // end position
engfunc(EngFunc_WriteCoord, Origin2[1])
engfunc(EngFunc_WriteCoord, Origin2[2])
write_short(g_SprESP) // sprite index
write_byte(3) // starting frame
write_byte(0) // frame rate in 0.1's
write_byte(1) // life in 0.1's
write_byte(Width) // line width in 0.1's
write_byte(0) // noise amplitude in 0.01's
write_byte(TargetColor[0])
write_byte(TargetColor[1])
write_byte(TargetColor[2])
write_byte(Brightness) // brightness)
write_byte(0) // scroll speed in 0.1's
message_end()
}
Show_FakeCrosshair(iPlayer)
{
set_dhudmessage(236, 135, 14, -1.0, -1.0, 0, 0.11, 0.11, 0.0, 0.0)
show_dhudmessage(iPlayer, "+")
}
Create_Laser(iPlayer)
{
static Float:StartOrigin[3], Float:EndOrigin[3]
Get_Position(iPlayer, 40.0, 0.0, 0.0, StartOrigin)
fm_get_aim_origin(iPlayer, EndOrigin)
message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
write_byte(TE_BEAMPOINTS)
engfunc(EngFunc_WriteCoord, StartOrigin[0])
engfunc(EngFunc_WriteCoord, StartOrigin[1])
engfunc(EngFunc_WriteCoord, StartOrigin[2])
engfunc(EngFunc_WriteCoord, EndOrigin[0])
engfunc(EngFunc_WriteCoord, EndOrigin[1])
engfunc(EngFunc_WriteCoord, EndOrigin[2])
write_short(g_SprLaser)
write_byte(0) // framerate
write_byte(0) // framerate
write_byte(5) // life
write_byte(10) // width
write_byte(0) // noise
write_byte(255) // r, g, b
write_byte(255) // r, g, b
write_byte(255) // r, g, b
write_byte(175) // brightness
write_byte(0) // speed
message_end()
}
Set_ProgessBarTime(iPlayer, Time)
{
message_begin(MSG_ONE_UNRELIABLE, g_MsgBarTime, {0, 0, 0}, iPlayer)
write_byte(Time)
write_byte(0)
message_end()
}
Create_EfZoom(iPlayer)
{
static Float:Origin[3], Float:Angles[3]
pev(iPlayer, pev_origin, Origin)
pev(iPlayer, pev_angles, Angles)
static Ent; Ent = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "info_target"))
if(!pev_valid(Ent))
return
set_pev(Ent, pev_classname, ZOOM_CLASSNAME)
set_pev(Ent, pev_owner, iPlayer)
set_pev(Ent, pev_movetype, MOVETYPE_FLY)
set_pev(Ent, pev_solid, SOLID_NOT)
engfunc(EngFunc_SetModel, Ent, ef_model)
fm_set_rendering(Ent, kRenderNormal, 255, 255, 255, kRenderTransAdd, 255)
set_pev(Ent, pev_origin, Origin)
set_pev(Ent, pev_angles, Angles)
set_pev(Ent, pev_nextthink, get_gametime() + 0.001)
}
public fw_Zoom_Think(Ent)
{
static Owner; Owner = pev(Ent, pev_owner)
if(!is_alive(Owner))
{
set_pev(Ent, pev_flags, FL_KILLME)
return
}
static iActiveItem; iActiveItem = get_pdata_cbase(Owner, 373, 5)
if(!IsValidPev(iActiveItem) || !IsCustomItem(iActiveItem))
{
set_pev(Ent, pev_flags, FL_KILLME)
return
}
if(get_pdata_int(iActiveItem, 30, 4) < 2)
{
set_pev(Ent, pev_flags, FL_KILLME)
return
}
static Float:Origin[3], Float:Angles[3]
pev(Owner, pev_origin, Origin)
pev(Owner, pev_angles, Angles)
set_pev(Ent, pev_origin, Origin)
set_pev(Ent, pev_angles, Angles)
set_pev(Ent, pev_nextthink, get_gametime() + 0.001)
}
//**********************************************
//* Safety Functions *
//**********************************************
public Register_SafetyFunc()
{
RegisterHam(Ham_Spawn, "player", "fw_Safety_Spawn_Post", 1)
RegisterHam(Ham_Killed, "player", "fw_Safety_Killed_Post", 1)
}
public Register_SafetyFuncBot(iPlayer)
{
RegisterHamFromEntity(Ham_Spawn, iPlayer, "fw_Safety_Spawn_Post", 1)
RegisterHamFromEntity(Ham_Killed, iPlayer, "fw_Safety_Killed_Post", 1)
}
public Safety_Connected(iPlayer)
{
Set_BitVar(g_IsConnected, iPlayer)
UnSet_BitVar(g_IsAlive, iPlayer)
}
public Safety_Disconnected(iPlayer)
{
UnSet_BitVar(g_IsConnected, iPlayer)
UnSet_BitVar(g_IsAlive, iPlayer)
}
public fw_Safety_Spawn_Post(iPlayer)
{
if(!is_user_alive(iPlayer))
return
Set_BitVar(g_IsAlive, iPlayer)
}
public fw_Safety_Killed_Post(iPlayer)
{
UnSet_BitVar(g_IsAlive, iPlayer)
}
public is_connected(iPlayer)
{
if(!(1 <= iPlayer <= 32))
return 0
if(!Get_BitVar(g_IsConnected, iPlayer))
return 0
return 1
}
public is_alive(iPlayer)
{
if(!is_connected(iPlayer))
return 0
if(!Get_BitVar(g_IsAlive, iPlayer))
return 0
return 1
}
//**********************************************
//* Create and check our custom weapon. *
//**********************************************
IsCustomItem(iItem)
{
return (pev(iItem, pev_impulse) == g_iszWeaponKey)
}
Weapon_Create(Float: Origin[3] = {0.0, 0.0, 0.0}, Float: Angles[3] = {0.0, 0.0, 0.0})
{
new iWeapon
static iszAllocStringCached
if (iszAllocStringCached || (iszAllocStringCached = engfunc(EngFunc_AllocString, WEAPON_BASE)))
{
iWeapon = engfunc(EngFunc_CreateNamedEntity, iszAllocStringCached)
}
if(!IsValidPev(iWeapon))
return FM_NULLENT
dllfunc(DLLFunc_Spawn, iWeapon)
set_pev(iWeapon, pev_origin, Origin)
set_pdata_int(iWeapon, 51, WEAPON_MAX_CLIP, 4)
set_pdata_int(iWeapon, 55, 0, 4)
set_pdata_int(iWeapon, 30, 0, 4)
set_pdata_int(iWeapon, 39, 0, 4)
set_pev(iWeapon, pev_impulse, g_iszWeaponKey)
set_pev(iWeapon, pev_angles, Angles)
engfunc(EngFunc_SetModel, iWeapon, w_model)
return iWeapon
}
Weapon_Give(iPlayer)
{
if(!IsValidPev(iPlayer))
{
return FM_NULLENT
}
new iWeapon, Float: vecOrigin[3]
pev(iPlayer, pev_origin, vecOrigin)
if((iWeapon = Weapon_Create(vecOrigin)) != FM_NULLENT)
{
Player_DropWeapons(iPlayer, ExecuteHamB(Ham_Item_ItemSlot, iWeapon))
set_pev(iWeapon, pev_spawnflags, pev(iWeapon, pev_spawnflags) | SF_NORESPAWN)
dllfunc(DLLFunc_Touch, iWeapon, iPlayer)
SetAmmoInventory(iPlayer, PrimaryAmmoIndex(iWeapon), WEAPON_DEFAULT_AMMO)
return iWeapon
}
return FM_NULLENT
}
Player_DropWeapons(iPlayer, iSlot)
{
new szWeaponName[32], iItem = get_pdata_cbase(iPlayer, 367 + iSlot, 5)
while(IsValidPev(iItem))
{
pev(iItem, pev_classname, szWeaponName, charsmax(szWeaponName))
engclient_cmd(iPlayer, "drop", szWeaponName)
iItem = get_pdata_cbase(iItem, 42, 4)
}
}
//**********************************************
//* Ammo Inventory. *
//**********************************************
PrimaryAmmoIndex(iItem)
{
return get_pdata_int(iItem, 49, 4)
}
GetAmmoInventory(iPlayer, iAmmoIndex)
{
if(iAmmoIndex == -1)
return -1
return get_pdata_int(iPlayer, 376 + iAmmoIndex, 5)
}
SetAmmoInventory(iPlayer, iAmmoIndex, iAmount)
{
if(iAmmoIndex == -1)
return 0
set_pdata_int(iPlayer, 376 + iAmmoIndex, iAmount, 5)
return 1
}
//**********************************************
//* Fire Bullets. *
//**********************************************
CallOriginalFireBullets(iItem, iPlayer)
{
state FireBullets: Enabled
static Float:g_Recoil[3]
pev(iPlayer, pev_punchangle, g_Recoil)
ExecuteHam(Ham_Weapon_PrimaryAttack, iItem)
set_pev(iPlayer, pev_punchangle, g_Recoil)
state FireBullets: Disabled
}
//**********************************************
//* Decals. *
//**********************************************
new Array: g_hDecals
public fw_DecalIndex_Post()
{
if(!g_hDecals)
{
g_hDecals = ArrayCreate(1, 1)
}
ArrayPushCell(g_hDecals, get_orig_retval())
}
UTIL_GunshotDecalTrace(iTrace, bool: bIsGunshot = false)
{
static iHit
static iMessage
static iDecalIndex
static Float:flFraction
static Float:vecEndPos[3]
iHit = INSTANCE(get_tr2(iTrace, TR_pHit))
if(iHit && !IsValidPev(iHit) || (pev(iHit, pev_flags) & FL_KILLME))
return
if(pev(iHit, pev_solid) != SOLID_BSP && pev(iHit, pev_movetype) != MOVETYPE_PUSHSTEP)
return
iDecalIndex = ExecuteHamB(Ham_DamageDecal, iHit, 0)
if(iDecalIndex < 0 || iDecalIndex >= ArraySize(g_hDecals))
return
iDecalIndex = ArrayGetCell(g_hDecals, iDecalIndex)
get_tr2(iTrace, TR_flFraction, flFraction)
get_tr2(iTrace, TR_vecEndPos, vecEndPos)
if(iDecalIndex < 0 || flFraction >= 1.0)
return
if(bIsGunshot)
{
iMessage = TE_GUNSHOTDECAL
}
else
{
iMessage = TE_DECAL
if(iHit != 0)
{
if(iDecalIndex > 255)
{
iMessage = TE_DECALHIGH
iDecalIndex -= 256
}
}
else
{
iMessage = TE_WORLDDECAL
if(iDecalIndex > 255)
{
iMessage = TE_WORLDDECALHIGH
iDecalIndex -= 256
}
}
}
engfunc(EngFunc_MessageBegin, MSG_PAS, SVC_TEMPENTITY, vecEndPos, 0)
write_byte(iMessage)
engfunc(EngFunc_WriteCoord, vecEndPos[0])
engfunc(EngFunc_WriteCoord, vecEndPos[1])
engfunc(EngFunc_WriteCoord, vecEndPos[2])
if(bIsGunshot)
{
write_short(iHit)
write_byte(iDecalIndex)
}
else
{
write_byte(iDecalIndex)
if(iHit)
{
write_short(iHit)
}
}
message_end()
}
//**********************************************
//* Set Animations. *
//**********************************************
stock Weapon_SendAnim(iPlayer, iItem, iAnim)
{
static i, iCount, iSpectator, aSpectators[32]
set_pev(iPlayer, pev_weaponanim, iAnim)
message_begin(MSG_ONE, SVC_WEAPONANIM, .player = iPlayer)
write_byte(iAnim)
write_byte(pev(iItem, pev_body))
message_end()
if(IsObserver(iPlayer))
return
get_players(aSpectators, iCount, "bch")
for(i = 0; i < iCount; i++)
{
iSpectator = aSpectators[i]
if(IsObserver(iSpectator) != OBS_IN_EYE || pev(iSpectator, pev_iuser2) != iPlayer)
continue
set_pev(iSpectator, pev_weaponanim, iAnim)
message_begin(MSG_ONE, SVC_WEAPONANIM, .player = iSpectator)
write_byte(iAnim)
write_byte(pev(iItem, pev_body))
message_end()
}
}
stock Player_SetAnimation(iPlayer, szAnim[])
{
#define ACT_RANGE_ATTACK1 28
// Linux extra offsets
#define extra_offset_animating 4
#define extra_offset_player 5
// CBaseAnimating
#define m_flFrameRate 36
#define m_flGroundSpeed 37
#define m_flLastEventCheck 38
#define m_fSequenceFinished 39
#define m_fSequenceLoops 40
// CBaseMonster
#define m_Activity 73
#define m_IdealActivity 74
// CBasePlayer
#define m_flLastAttackTime 220
new iAnimDesired, Float:flFrameRate, Float:flGroundSpeed, bool:bLoops
if((iAnimDesired = lookup_sequence(iPlayer, szAnim, flFrameRate, bLoops, flGroundSpeed)) == -1)
{
iAnimDesired = 0
}
static Float:flGametime; flGametime = get_gametime()
set_pev(iPlayer, pev_frame, 0.0)
set_pev(iPlayer, pev_framerate, 1.0)
set_pev(iPlayer, pev_animtime, flGametime)
set_pev(iPlayer, pev_sequence, iAnimDesired)
set_pdata_int(iPlayer, m_fSequenceLoops, bLoops, extra_offset_animating)
set_pdata_int(iPlayer, m_fSequenceFinished, 0, extra_offset_animating)
set_pdata_float(iPlayer, m_flFrameRate, flFrameRate, extra_offset_animating)
set_pdata_float(iPlayer, m_flGroundSpeed, flGroundSpeed, extra_offset_animating)
set_pdata_float(iPlayer, m_flLastEventCheck, flGametime , extra_offset_animating)
set_pdata_int(iPlayer, m_Activity, ACT_RANGE_ATTACK1, extra_offset_player)
set_pdata_int(iPlayer, m_IdealActivity, ACT_RANGE_ATTACK1, extra_offset_player)
set_pdata_float(iPlayer, m_flLastAttackTime, flGametime , extra_offset_player)
}
//**********************************************
//* Kick back. *
//**********************************************
Weapon_KickBack(iItem, iPlayer, Float:upBase, Float:lateralBase, Float:upMod, Float:lateralMod, Float:upMax, Float:lateralMax, directionChange)
{
static iDirection
static iShotsFired
static Float: Punchangle[3]
pev(iPlayer, pev_punchangle, Punchangle)
if((iShotsFired = get_pdata_int(iItem, 64, 4)) != 1)
{
upBase += iShotsFired * upMod
lateralBase += iShotsFired * lateralMod
}
upMax *= -1.0
Punchangle[0] -= upBase
if(upMax >= Punchangle[0])
{
Punchangle[0] = upMax
}
if((iDirection = get_pdata_int(iItem, 60, 4)))
{
Punchangle[1] += lateralBase
if(lateralMax < Punchangle[1])
{
Punchangle[1] = lateralMax
}
}
else
{
lateralMax *= -1.0;
Punchangle[1] -= lateralBase
if(lateralMax > Punchangle[1])
{
Punchangle[1] = lateralMax
}
}
if(!random_num(0, directionChange))
{
set_pdata_int(iItem, 60, !iDirection, 4)
}
set_pev(iPlayer, pev_punchangle, Punchangle)
}
//**********************************************
//* Some useful stocks. *
//**********************************************
stock Get_Position(iPlayer, Float:forw, Float:right, Float:up, Float:vStart[])
{
new Float:Origin[3], Float:Angles[3], Float:vForward[3], Float:vRight[3], Float:vUp[3]
pev(iPlayer, pev_origin, Origin)
pev(iPlayer, pev_view_ofs,vUp) //for player
xs_vec_add(Origin, vUp, Origin)
pev(iPlayer, pev_v_angle, Angles) // if normal entity ,use pev_angles
angle_vector(Angles, ANGLEVECTOR_FORWARD, vForward) //or use EngFunc_AngleVectors
angle_vector(Angles, ANGLEVECTOR_RIGHT, vRight)
angle_vector(Angles, ANGLEVECTOR_UP, vUp)
vStart[0] = Origin[0] + vForward[0] * forw + vRight[0] * right + vUp[0] * up
vStart[1] = Origin[1] + vForward[1] * forw + vRight[1] * right + vUp[1] * up
vStart[2] = Origin[2] + vForward[2] * forw + vRight[2] * right + vUp[2] * up
}